@ECHO OFF
REM Copie un dossier et ses sous-dossiers dans DropBox (ou autre dossier synchronis‚ sur un serveur)
REM en ajoutant la date du jour au dossier principal
REM Cr‚e ‚galement un script SQL de la base de donn‚es MySQL et le copie dans le mˆme dossier dans DropBox
REM Note : Pour que les accents pr‚sents dans les echo s'affichent correctement, utiliser l'encodage OEM 720.
REM Note : Si des noms de dossiers contiennent des caractŠres accentu‚s, utilisez l'encodage ANSI
REM        et ajoutez l'instruction CHCP 1252.
REM Programm‚ par Christiane Lagac‚ : http://christianelagace.com
REM Le 26 mars 2013
REM Ajust‚ par Christiane Lagac‚
REM Le 17 octobre 2015
REM Modifications : Toutes les configurations sont maintenant dans des variables

REM *************************
REM ***** Configuration *****
REM *************************

REM ***** VOUS DEVEZ REMPLIR CETTE SECTION *****

REM Nom du dossier contenant le projet … sauvegarder (ex : monprojet)
set dossierSource=monprojet

REM Chemin pour acc‚der … ce dossier. Placer entre guillemets s'il contient des espaces 
REM (ex : "C:\Program Files (x86)\EasyPHP-DevServer-14.1VC11\data\localweb")
set cheminSource="C:\Program Files (x86)\EasyPHP-DevServer-14.1VC11\data\localweb"

REM Nom du dossier dans lequel le projet doit ˆtre copi‚. Le dossier sera cr‚‚ sur DropBox, 
REM avec la date du jour … la fin de son nom (ex : monprojet)
set dossierCible=monprojet

REM Chemin du dossier DropBox (ex : C:\Users\VotreNom\Dropbox)
set cheminCible=C:\Users\VotreNom\Dropbox

REM Chemin du dossier contenant le fichier mysqldump.exe 
REM (ex : "C:\Program Files (x86)\EasyPHP-DevServer-14.1VC11\binaries\mysql\bin")
set cheminMySQLBin="C:\Program Files (x86)\EasyPHP-DevServer-14.1VC11\binaries\mysql\bin"

REM Nom de l'usager MySQL qui d‚tient les droit requis pour sauvegarder la base de donn‚es
set usagerMySQL=root

REM Nom de la base de donn‚es … sauvegarder
set nomBD=mabd

REM *****************************
REM ***** Fin configuration *****
REM *****************************

REM ***** Cr‚ation des variables pour la date *****
REM La commande "WMIC OS GET localdatetime" retrouve la date au format ISO. 
REM Le caractŠre ^ (caret) est un caractŠre d'‚chappement. 
REM Le caractŠre | (pipe) permet de rediriger la sortie de WMIC vers la commande find. 
REM Puisqu'on veut conserver toute la chaŒne, on recherche n'importe quel caractŠre : find "."
REM Autrement dit, cette ligne place toute la date dans la variable dateISO.

for /f %%a in ('WMIC OS Get localdatetime  ^| find "."') do set dateISO=%%a
set annee=%dateISO:~0,4%
set mois=%dateISO:~4,2%
set jour=%dateISO:~6,2%

echo *************************
echo ***** Copie du site *****
echo *************************

@echo on
XCOPY %cheminSource%\%dossierSource%\* %cheminCible%\%dossierCible%-%annee%-%mois%-%jour% /S /I
@echo off

echo ***********************************************
echo ***** Cr‚ation du script pour la BD MySQL *****
echo ***********************************************

@echo on
CD %cheminMySQLBin%
mysqldump -u %usagerMySQL% -p %nomBD% > %cheminCible%\%dossierCible%-%annee%-%mois%-%jour%\%nomBD%-%annee%-%mois%-%jour%.sql
@echo off

echo *******************
echo ***** Termin‚ *****
echo *******************
echo.
echo Les fichiers ont ‚t‚ copi‚s dans le dossier
echo %cheminCible%\%dossierCible%-%annee%-%mois%-%jour%
echo.
PAUSE